En el ámbito profesional, la correcta manipulación de datos es fundamental para la toma de decisiones acertadas. En esta ocasión, nos enfocaremos en la importancia de eliminar los números de un texto en Excel y cómo puede impactar positivamente en la calidad y claridad de la información presentada. Revisaremos la forma más compleja y simple de separar los números de un texto en Excel.
Eliminar números con la función SUSTITUIR
Para eliminar los números de una cadena alfanumérica en Excel, existen varias opciones. Una de ellas es utilizar una fórmula basada en la función SUSTITUIR. Aunque esta fórmula puede ser bastante larga, pero es una de las formas más sencillas que nos permite lograrlo. En este caso al usar esta función, implica anidar las funciones SUSTITUIR 10 veces (una por cada número del 0 al 9) para obtener el resultado deseado. La fórmula con la función sustituir quedaría de la siguiente manera.
=SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(SUSTITUIR(
A2;1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;"");0;"")
Y ejecutado en Excel obtendríamos el siguiente resultado:
Cómo observas la fórmula se hace muy larga si usamos sólo la función SUSTITUIR, pero en Excel todo es posible, podemos hacerlo mucho más corta esta fórmula si usamos una cadena de Funciones de forma matricial.
Eliminar números usando UNIRCADENAS
Cabe mencionarte que la función UNIRCADENAS es una de las nuevas de Excel que ha venido integrándose a partir de las versiones 2019 en adelante y por supuesto la 365. Entonces para eliminar los números de una cadena de texto o datos alfanuméricas, también es posible si combinamos varias funciones para obtener una fórmula de matriz compleja o matricial. Estas funciones que nos permiten tal objetivos son: UNIRCADENAS, EXTRAE, FILA, LARGO e INDIRECTO. La fórmula sería como la que te mostramos:
=UNIRCADENAS("";VERDADERO;SI(ESERR(EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1)+0);EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1);""))
Ejecutado en Excel nos quedaría:
Cómo puedes observar también es posible extraer los números usando este tipo de fórmulas matriciales. Pero para que lo comprendas mucho mejor vamos por partes.
Paso 01 : Función EXTRAE
La Función EXTRAE es una Función de tipo Texto que nos devuelve el texto disponible en una celda. Y tiene 3 argumentos, (texto;posicion_inicial;numero_de_caracteres). Entonces para que esta función funciones debemos de indicar el texto inicial o argumento uno y el número de caracteres a devolver o el argumento 3. Para el argumento del número de inicio (posición inicial) en la función EXTRAE, utilizaremos la lista de array resultante de las funciones FILA, INDIRECTO y LARGO.
=FILA(INDIRECTO("1:"&LARGO(A2)))
Ejecutado en Excel tendríamos una matriz dinámica que enumera el número de caracteres que tiene el texto en este caso de la celda A2:
Si todo lo anterior lo usamos como el argumento dos de la función EXTRAE o posición inicial de la función EXTRAE, con valor de 1 para el argumento numero de caracteres, lo que nos devolverá es un array tal como te mostramos a continuación:
=EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1)
Ejecutado en Excel tendríamos:
Si observas tenemos un array pero ya no de la cantidad de cifras, sino del valor de las cifras de lo que contienen la celda A2.
PASO 02: Validando que sea una cifra numérica
Si sumamos un cero (+0) al al final de la función EXTRAE validaremos si este es un número o un texto. Ya que si el valor es un Texto generará un error de tipo #¡VALOR!. Por lo tanto si añadimos un cero al final de EXTRAE vamos a tener un nuevo array con valores numéricos y errores:
=EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1)+0
Ejecutado en Excel se vería cómo:
De esta forma hemos validado que cuándo la cifra sea un texto o un caracter no numérico a propósito nos genere un error, mientras que si es un número tal cifra permanecerá invariable. Otra forma de validar esto es multiplicando por 1.
PASO 03: Convirtiendo a Falsos y Verdaderos
Lugo vamos a usar la función ESERR para que cada valor que es un error sea convertido VERDADERO y un FALSO para los valores no erróneos o que son números, dando un resultado como salida salida una nueva matriz de VERDADERO y FALSO, donde VERDADERO será para los caracteres no numéricos y FALSO será para caracteres los números.
Ejecutado en Excel tendríamos:
=ESERR(EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1)+0)
De esta forma comprobamos que cada valor verdadero es un error y a la misma vez un texto, y cada valor de falso es un caracter de número.
PASO 04: Validamos el TEXTO con función SI
Ahora vamos a implementar la función SI. En esta parte la función SI confirmará el resultado que hemos obtenido de la función ESERR (Paso 3). Si el resultado es VERDADERO, devolverá una nueva matriz de todos los caracteres de una cadena texto alfanumérica. Para eso, hemos adicionado otra función EXTRAE sin añadir cero al final para el argumento falso de la función SI. De esta forma si el valor de la función ESERR devuelve un FALSO, que representa a los números, simplemente mostrará un espacio en blanco (""). De esta forma, tendremos un array que contiene sólo los caracteres texto.
=SI(ESERR(EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1)+0);EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1);"")
Ejecutado en Excel tendríamos:
PASO 05: Consolidamos el resultado
Como último paso consolidamos el resultado de la función usando UNIRCADENAS. Esta función UNIRCADENAS reunirá todos los caracteres de la matriz anterior ignorando la cadena vacía. En el delimitador para esta función se establece cómo un vacío y el valor del argumento ignorar_vacios se será como VERDADERO. Esto nos dará el resultado de solo textos, es decir, sólo los caracteres no numéricos de la cadena alfanumérica que antes habíamos tenido.
{=UNIRCADENAS("";VERDADERO;SI(ESERR(EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1)+0);
EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1);""))}
El resultado se muestra en la imagen siguiente:
Notas Importantes
La fórmula que acabamos de construir es de tipo matricial, y cuándo estas se introducen en Excel 2019 o anterior, es obligatorio usar CTRL + SHIFT + ENTER para validar en la celda de Excel, esto realizar en lugar de solo ENTER normal. Pero si tienes una versión de Excel superior a la mencionada es más probable que ya no sea necesario tal combinación de teclas. Reconocerás que lo has hecho correctamente cuando se muestran las llaves al inicio y final de la fórmula. NO escribas estas llaves manualmente, porque si lo hace la fórmula no funcionará.
Publicar un comentario